mgr gnuplot demo

#
# $Id: mgr.dem,v 1.4 1997/01/05 22:03:11 drd Exp $
#
pause 0 "Watch some  cubic splines"
set samples 50
set xlabel "Angle (deg)"
set ylabel "Amplitude"
set title "Brag-Reflex -- Peak only"
plot "big_peak.dat" title "Rate" with errorbars, \
                 "" smooth csplines t "Rate"

set bars small
replot
set bars large
#

set samples 300
set xlabel "Time (sec)"
set ylabel "Rate"
set title "Ag 108 decay data"
plot "silver.dat" t "experimental" w errorb, \
               ""  smooth csplines t "cubic smooth"
# error is column 3; weight larger errors less
# start with rel error = 1/($3/$2)

S=1
plot "silver.dat" t "experimental" w errorb,\
               "" u 1:2:(S*$2/$3) smooth acsplines t "acspline Y/Z"

plot "silver.dat" t "rate" w errorb,\
               "" u 1:2:($2/($3*1.e1)) sm acs t "acspline Y/(Z*1.e1)",\
               "" u 1:2:($2/($3*1.e3)) sm acs t "         Y/(Z*1.e3)",\
               "" u 1:2:($2/($3*1.e5)) sm acs t "         Y/(Z*1.e5)"

set logscale y
replot

set nologscale y
plot "silver.dat" t "experimental" w errorb,\
               "" smooth sbezier t "bezier"

set logscale y
plot "silver.dat" t "rate" w errorb, \
               "" smooth sbezier t "bezier"
#

set samples 100
set nologscale
set xlabel "Resistance [Ohm]"
set ylabel "Power [W]"
set title "UM1-Cell Power"
n(x)=1.53**2*x/(5.67+x)**2
plot [0:50] "battery.dat" t "Power" with xyerrorbars, n(x) t "Theory" w lines

plot [0:50] "battery.dat" t "Power" with boxxy, n(x) t "Theory" w lines

plot [0:50] "battery.dat" u 1:2:3 t "Power" w xerr, n(x) t "Theory" w lines

plot [0:50] "battery.dat" u 1:2:4 t "Power" w yerr, n(x) t "Theory" w lines

set logscale y
plot [0:50] "battery.dat" u 1:2:4 t "Power" w yerr, n(x) t "Theory" w lines

set logscale xy
plot [1:50] "battery.dat" t "Power" w xyerr, n(x) t "Theory" w lines

set nologscale
set bars small
plot [0:50] "battery.dat" t "Power" with xyerrorbars, n(x) t "Theory" w lines

plot [0:50] "battery.dat" u 1:2:3 t "Power" w xerr, n(x) t "Theory" w lines

plot [0:50] "battery.dat" u 1:2:4 t "Power" w yerr, n(x) t "Theory" w lines
set bars large

set xlabel ""
set ylabel ""
set title ""